//BRICK ATTACK par Walter Siracusa

function clearGame(){
	Mouse.show(); //Montre le pointeur
	end_mc.removeMovieClip();
	for(i=0;i<Nb_brk0;i++) _root["brk"+i].removeMovieClip();
	for(i=0;i<NB_BONUS;i++)
		if(Tab_bonus[i]) _root["bonus_mc"+i].removeMovieClip();
	nextFrame();
}

function endGame(val){
	onEnterFrame=function(){};
	clip=attachMovie("end_mc","end_mc",_root.getNextHighestDepth(),{_x:84,_y:105});
	clip.gotoAndPlay("perdu");
}

BRICK_H=12; //Nb de brique horizontalement
BRICK_V=4;  //Nb de briques verticalement
NB_BONUS=6; //Nb de bonus maximum en même temps

//Mouse.hide(); //Cache le pointeur de la souris
balle.h=random(2); //Déplacement horizontale: true = à droite, false = à gauche 
balle.v=false; //Déplacement verticale: true = en bas, false = en haut
balle.vt=3; //Vitesse de la balle
Timer_bonus=getTimer();
Score=0;
Push_brick=0;

Tab_bonus=new Array(NB_BONUS);
for(i=0;i<20;i++) Tab_bonus[i]=false;

//Association des sons
Snd_balle=new Sound();
Snd_balle.attachSound("barre.mp3");
Snd_brique=new Sound();
Snd_brique.attachSound("brique.mp3");
Snd_ok=new Sound();
Snd_ok.attachSound("bonus_ok.wav");
Snd_ko=new Sound();
Snd_ko.attachSound("bonus_ko.wav");

//Affichage des  briques
Depth=0;
Nb_brk=0; //Nombre de briques
for(j=1;j<=BRICK_V;j++){
	for(i=0;i<BRICK_H;i++){
		brick=attachMovie("brique"+j,"brk"+Nb_brk,Depth++,{_x:i*32,_y:20+(j-1)*16});
		if(j==1) brick.life=2; //Brique rouge plus résistante
		else brick.life=1;
		Nb_brk++;
	}
}
Nb_brk0=Nb_brk; //Nombre de briques initiales

onEnterFrame=function(){
	//Raquette à l'abscisse du pointeur 
	barre_mc._x=_xmouse;
	
	//Déplacement horizontal   
	if(balle.h) balle._x+=balle.vt; //A droite
	else balle._x-=balle.vt; //A gauche
	//Déplacement vertical
	if(balle.v) balle._y+=balle.vt; //En bas
	else balle._y-=balle.vt; //En haut
	
	//La balle quitte la scène
	if(balle._y<0){ //En haut
		balle._y=0;
		balle.v=true;
		Snd_balle.start();
	}else if(balle._x<0){ //A gauche
		balle._x=0;
		balle.h=true;
		Snd_balle.start();
	}else if(balle._x>374){ //A droite
		balle._x=374;
		balle.h=false;
		Snd_balle.start();
	}else if(balle._y>390) endGame("perdu"); //En bas => Game Over
			
	//Collision de la balle sur la raquette
	if(balle.hitTest(barre_mc)){ //Collision !
		balle.v=false;
		Snd_balle.start();
		barre_mc.gotoAndPlay(2);
		balle.vt=4+random(3); //4,5 ou 6
		
		//Toutes les briques descendent...
		if(++Push_brick<30){
			for(i=0;i<Nb_brk0;i++)
				if(_root["brk"+i]!=undefined) _root["brk"+i]._y+=8;
		}
	}
		
	//Collision de la balle sur une brique
	for(i=0;i<Nb_brk0;i++){
		brick=_root["brk"+i];
		if(balle.hitTest(brick)){//Collision !
			brick.play(); //Anime la brique (et la détruit)
			Score+=5;
			score_txt.text=Score;
			
			//Rebond en fonction de sa position par rapport à la brique: 8 cas
			if(balle.v){//La balle descend...
				if(balle.h){ //...vers la droite
					if(balle._x<brick._x) balle.h=false; //A gauche de la brique
					else balle.v=false; //Au dessus de la brique
				}else{ //...vers la gauche
					if(balle._y<brick._y) balle.v=false; //Au dessus de la brique
					else balle.h=true; //A droite de la brique
				}
			}else{ //La balle monte...
				if(balle.h){ //...vers la droite
					if(balle._x<brick._x) balle.h=false; //A gauche de la brique
					else balle.v=true; //Sous la brique
				}else{ //...vers la gauche
					if(balle._y+balle.vt>brick._y+15) balle.v=true; //Sous la brique
					else balle.h=true; //A droite de la brique
				}
			}
			
			//Libère un bonus
			if(getTimer()>Timer_bonus+500 && Nb_brk>1){ //Pas de bonus à la dernière brick
				Timer_bonus=getTimer();
				
				for(b=0;b<NB_BONUS;b++){
					if(!Tab_bonus[b]){
						Tab_bonus[b]=true;
						clip=attachMovie("bonus_mc","bonus_mc"+b,_root.getNextHighestDepth());
						clip._x=brick._x+15;
						clip._y=brick._y;
						clip.idx=b;
						clip.took=false;
						if(random(2)){ //Positif 
							switch(random(4)){
								case 0: clip.val=15;break;
								case 1: clip.val=30;break;
								case 2: clip.val=50;break;
								case 3: clip.val=75;break;
							}
							clip.point_txt.text="+"+clip.val;
						}else{ //Negatif
							switch(random(3)){
								case 0: clip.val=-5;break;
								case 1: clip.val=-10;break;
								case 2: clip.val=-15;break;
							}
							clip.point_txt.text=clip.val;
						}
						break;  //Quitte la boucle
					}
				}
			}
			Snd_brique.stop(); //Stop le son
			Snd_brique.start(); //Joue le son
			break; //Quitte la boucle
		}
	}
	
	//Chute des bonus et collision avec la raquette
	for(i=0;i<NB_BONUS;i++){
		if(Tab_bonus[i]){
			clip=_root["bonus_mc"+i];
			clip._y+=2;
			if(clip._y>420) clip.play();
			if(!clip.took && barre_mc.hitTest(clip)){
				Score+=clip.val;
				if(Score<0) Score=0;
				score_txt.text=Score;
				clip.took=true;
				clip.play();
				if(clip.val>0) Snd_ok.start();
				else Snd_ko.start();
			}
		}
	}
	
	if(Nb_brk==0){ 
		Score+=250;
		score_txt.text=Score;
		endGame("gagne"); //Toutes les briques détruites => Yesss!!!
	}
}