//COPIEUR par Walter Siracusa

import flash.display.BitmapData;

function newGrille(){
	//Grille source
	bmp_src=BitmapData.loadBitmap("img"+Num_img+".png");
		
	for(j=0;j<HT_GRILLE;j++)
		for(i=0;i<LG_GRILLE;i++){ 
			pix=bmp_src.getPixel(i,j);
			
			clip=_root["bloc_src_mc"+(j*LG_GRILLE+i)];
			if(pix==0){ //Noir
				Tab_src[i][j]=1;
				clip.gotoAndPlay("on");
			}else{ //Blanc
				Tab_src[i][j]=0;
				clip.gotoAndPlay("off");
			}
		}
	
	//Grille destination
	for(j=0;j<HT_GRILLE;j++)
		for(i=0;i<LG_GRILLE;i++){
			Tab_dst[i][j]=0;
			_root["bloc_dst_mc"+(j*LG_GRILLE+i)].gotoAndPlay("off");
		}
}

function checkGrille(){
	ok=true;
	for(j=0;j<HT_GRILLE;j++){
		for(i=0;i<LG_GRILLE;i++){
			if(Tab_src[i][j]!=Tab_dst[i][j]){ 
				ok=false;
				break;
			}
		}
		if(!ok) break;
	}
	
	if(ok){ //Grille complétée
		Num_img++;
		yes_mc.play();
	}
}

//-------------------------------

LG_GRILLE=19;
HT_GRILLE=12;

LG_BLOC=18;
HT_BLOC=18;
NB_BLOC=LG_GRILLE*HT_GRILLE;

Y_DST=HT_GRILLE*HT_BLOC+4;

NB_IMG=3; //Nombre d'image

Tab_src=new Array(LG_GRILLE);
Tab_dst=new Array(LG_GRILLE);

for(i=0;i<LG_GRILLE;i++){
	Tab_src[i]=new Array(HT_GRILLE);
	Tab_dst[i]=new Array(HT_GRILLE);
}

Game=1; //Etat du jeu
Draw=false; //Bouton enfoncé
i_dst0=-1;
j_dst0=-1;
Num_img=1; //N° de l'image courante
abandon_but._visible=false;
Score=4000;
score_txt.text=Score;

//Grille source
k=0;
for(j=0;j<HT_GRILLE;j++) 
	for(i=0;i<LG_GRILLE;i++){
		clip=attachMovie("bloc_mc","bloc_src_mc"+k++,_root.getNextHighestDepth());
		clip._x=i*LG_BLOC;
		clip._y=j*HT_BLOC;
	}

//Grille destination
k=0;
for(j=0;j<HT_GRILLE;j++) 
	for(i=0;i<LG_GRILLE;i++){
		clip=attachMovie("bloc_mc","bloc_dst_mc"+k++,_root.getNextHighestDepth());
		clip._x=i*LG_BLOC;
		clip._y=Y_DST+j*HT_BLOC;
		clip.onRelease=function(){}; //Pour avoir le doigt pointé
	}

//YES
attachMovie("yes_mc","yes_mc",_root.getNextHighestDepth(),{_x:168,_y:218});

_root.onMouseDown=function(){
	Draw=true;
}

_root.onMouseUp=function(){
	Draw=false;
	i_dst0=-1;
	j_dst0=-1;
}

function endGame(){
	for(i=0;i<NB_BLOC;i++){
		_root["bloc_src_mc"+i].removeMovieClip();
		_root["bloc_dst_mc"+i].removeMovieClip();
	}
	yes_mc.removeMovieClip();
	onEnterFrame=function(){};
	nextFrame();
}

abandon_but.onRelease=function(){
	endGame();
}

_root.onEnterFrame=function(){
	if(Game==1){
		//342 = LG_GRILLE*LG_BLOC, 436= Y_DST+HT_GRILLE*HT_BLOC
		if(Draw && _xmouse>=0 && _xmouse<342 && _ymouse>Y_DST && _ymouse<436){
			i_dst=Math.floor(_xmouse/LG_BLOC);
			j_dst=Math.floor((_ymouse-Y_DST-1)/HT_BLOC);
			if(i_dst!=i_dst0 || j_dst!=j_dst0){
				i_dst0=i_dst;
				j_dst0=j_dst;
				Tab_dst[i_dst][j_dst]=1-Tab_dst[i_dst][j_dst]; //Inverse les valeurs 0 ou 1
				clip=_root["bloc_dst_mc"+(j_dst*LG_GRILLE+i_dst)];
				if(Tab_dst[i_dst][j_dst]==1) clip.gotoAndPlay("on");
				else clip.gotoAndPlay("off");
				checkGrille();
			}
		}
		//Score
		if(Score>0){ 
			Score--;
			score_txt.text=Score;
			//Apparition du bouton d'abandon
			if(Score==3500) abandon_but._visible=true;
		}
	}else if(Game==3){ //End Game
		endGame();
	}
}

newGrille();