//VIRUS par Walter Siracusa

_root.onEnterFrame=function(){
	//HEART
	if(Key.isDown(Key.UP) && heart_mc._y>45) heart_mc._y-=HEART_VT;
	if(Key.isDown(Key.RIGHT) && heart_mc._x<Stage.width-15) heart_mc._x+=HEART_VT;
	if(Key.isDown(Key.DOWN) && heart_mc._y<Stage.height-15) heart_mc._y+=HEART_VT;
	if(Key.isDown(Key.LEFT) && heart_mc._x>15) heart_mc._x-=HEART_VT;					 
	
	//Déplace heart0_mc selon heart_mc
	heart0_mc._x=heart_mc._x;
	heart0_mc._y=heart_mc._y;
	
	//VIRUS
	for(i=0;i<Nb_virus;i++){
		//Colision avec heart_mc
		if(heart0_mc.hitTest(clip)){ 
			if(Nrj>=4){ 
				Nrj-=4;
				if(Nrj==152){
					heart_snd.start(0,1000);
				}else if(Nrj==72){ //Nrj critique...
					heart_mc.gotoAndPlay("fast");
					band_mc.nrj_mc.play();
					zik_snd.stop();
				}
				band_mc.nrj_mc._width=Nrj;
			}else if(Nrj==0){ //GAME OVER
				Nrj=-1;
				heart_snd.stop();
				heart_mc.gotoAndPlay("dead");
				for(v=0;v<Nb_virus;v++)	_root["virus_mc"+v].gotoAndPlay("end");
				clearInterval(id_addVirus);
				clearInterval(id_upScore);
				heart0_mc.play(); //nextFrame + detruit band_mc
				break;
			}
		}
		
		//Déplacement
		clip=_root["virus_mc"+i];
		clip._x+=clip.vtx;
		clip._y+=clip.vty;
		
		//Sortie => Replacement aléatoire
		if(clip._x<-30 || clip._x>Stage.width+30 || clip._y<-30 || clip._y>Stage.height+30) initVirus(clip);
	}
}

function initVirus(mc){
	switch(random(4)){ 
		case 0: //HAUT 
			mc._x=random(Stage.width);
			mc._y=-30;
			mc.vtx=0;
			mc.vty=random(4)+1;
			break;
		case 1: //DROITE
			mc._x=Stage.width+30;
			mc._y=random(Stage.height);
			mc.vtx=-(random(5)+1);
			mc.vty=0;
			break;
		case 2: //BAS 
			mc._x=random(Stage.width);
			mc._y=Stage.height+30;
			mc.vtx=0;
			mc.vty=-(random(4)+1);
			break;
		case 3: //GAUCHE
			mc._x=-30;
			mc._y=random(Stage.height);
			mc.vtx=random(5)+2;
			mc.vty=0;
			break;
	}
}

function addVirus(){
	if(Nb_virus<NB_VIRUS_MAX){
		clip=_root.attachMovie("virus_mc","virus_mc"+Nb_virus++,_root.getNextHighestDepth());
		initVirus(clip);
		band_mc.swapDepths(_root.getNextHighestDepth());
	}
}

function upScore(){
	Score++;
	band_mc.score_txt.text=Score;
}

//-----------------------

HEART_VT=5;
NB_VIRUS_MAX=40;
Nb_virus=0;
heart0_mc._visible=false;
_root.attachMovie("band_mc","band_mc",_root.getNextHighestDepth(),{_x:0,_y:0});
Nrj=252;
Score=0;

heart_snd=new Sound();
heart_snd.attachSound("heart.mp3");
zik_snd.start(0,1000);

id_addVirus=setInterval(addVirus,1000);
id_upScore=setInterval(upScore,175);