//PONG par Walter Siracusa

pbar_mc.vt=4;
cbar_mc.vt=6.7;
cscore=0;
Score=0;
timer0=getTimer();
alterne=random(2);

block_snd=new Sound();
block_snd.attachSound("block.wav");
coin_snd=new Sound();
coin_snd.attachSound("coin.mp3");
people_snd=new Sound();
people_snd.attachSound("people.mp3");
bell_snd=new Sound();
bell_snd.attachSound("bell.mp3");

function initBalle(){
	balle_mc._x=275;
	balle_mc._y=200;
	alterne=1-alterne;
	balle_mc.h=alterne;
	balle_mc.v=random(2);
	balle_mc.vtx=4;
	balle_mc.vty=4
	balle_mc.mov=0;
	balle_mc.timer=getTimer()+2000;
	balle_mc.hit="none";
}

initBalle();

_root.onEnterFrame=function(){
	//Raquette du joueur
	if(Key.isDown(Key.UP) && pbar_mc._y>40) pbar_mc._y-=pbar_mc.vt;
	else if(Key.isDown(Key.DOWN) && pbar_mc._y<360) pbar_mc._y+=pbar_mc.vt;
	 
	//Raquette du CPU
	if(balle_mc._y<cbar_mc._y && cbar_mc._y>40) cbar_mc._y-=cbar_mc.vt;
	if(balle_mc._y>cbar_mc._y && cbar_mc._y<360) cbar_mc._y+=cbar_mc.vt;
	
	//Collision de la balle en haut et en bas
	if(balle_mc._y<8) balle_mc.v=1;
	else if(balle_mc._y>392) balle_mc.v=0;
	
	//Collision de la balle sur la raquettes du joueur
	if(balle_mc.hitTest(pbar_mc) && balle_mc._x>18){ 
		balle_mc.h=1;
		balle_mc.vtx=random(4)+6;
		balle_mc.vty=random(4)+6;
		balle_mc.hit="p";
		pbar_mc.play();
		Score+=25;
		pscore_txt.text=Score;
		block_snd.start();
	}//Collision de la balle sur la raquettes du CPU
	else if(balle_mc.hitTest(cbar_mc) && balle_mc._x<535){ 
		balle_mc.h=0;
		balle_mc.vtx=random(4)+6;
		balle_mc.vty=random(4)+6;
		balle_mc.hit="c";
		cbar_mc.play();
		cscore+=25;
		cscore_txt.text=cscore;
		block_snd.start();
	}
	
	//Collision de la balle sur un pod
	for(i=1;i<=4;i++){
		clip=_root["pod"+i+"_mc"];
		if(clip.hitTest(balle_mc) && clip._currentframe==20 && balle_mc.hit!="none"){ 
			clip.play();
			coin_snd.start();
			if(balle_mc.hit=="p"){ //Joueur ramasse une pod
				Score+=15;
				pscore_txt.text=Score;
			}else{ //CPU ramasse un pod
				cscore+=15;
				cscore_txt.text=cscore;
			}
		}
	}
	
	//La balle sort du jeu => Replacée
	if(balle_mc._x<0){ //Joueur perd la balle
		initBalle();
		//Joueur perd des points
		if(Score>=30) Score-=30;
		else Score=0;
		pscore_txt.text=Score;
		//CPU gagne des points
		cscore+=30;
		cscore_txt.text=cscore;
	}else if(balle_mc._x>550){ //CPU perd la balle
		initBalle();
		//CPU perd des points
		if(cscore>=30) cscore-=30;
		else cscore=0;
		cscore_txt.text=cscore;
		//Joueur gagne des points
		Score+=30;
		pscore_txt.text=Score;
		
		people_snd.start();
	}
	
	//Déplacement de la balle
	if(balle_mc.mov){
		//Horizontal
		if(balle_mc.h) balle_mc._x+=balle_mc.vtx;
		else balle_mc._x-=balle_mc.vtx;
		
		//Vertical
		if(balle_mc.v) balle_mc._y+=balle_mc.vty;
		else balle_mc._y-=balle_mc.vty;
	}
	else if(getTimer()>balle_mc.timer){ //La balle démarre
		balle_mc.mov=1;
		bell_snd.start();
	}
	
	if(getTimer()>timer0+90000){
		//Points bonus pour le gagnant
		if(Score>cscore){ 
			Score+=100;
			pscore_txt.text=Score;
		}else if(Score<cscore){
			cscore+=100;
			cscore_txt.text=cscore;
		}
		bell_snd.start();
		_root.onEnterFrame=function(){};
		_root.gotoAndPlay(3);
	}
}